[Visual Basic 6.0] TQC 企業人才技能認證 Visual Basic 程式設計 - 401 簡易文書編輯器 | 0xDe - 點部落

2013-11-03

[Visual Basic 6.0] TQC 企業人才技能認證 Visual Basic 程式設計 - 401 簡易文書編輯器

摘要: [Visual Basic 6.0] TQC 企業人才技能認證 Visual Basic 程式設計 - 401 簡易文書編輯器

[Visual Basic 6.0] TQC 企業人才技能認證 Visual Basic 程式設計 - 401 簡易文書編輯器


' 一開始必須先載入 CommonDialog 物件 方法 => 專案(P) => 設定使用元件 (O) =>
' 找到 "Microsoft Common Dialog Control 6.0" 將它打勾後 確定 即可 。
' 之後拉一個 CommonDialog 物件到表單上將物件名稱 (Name) 改成 "CMDialog" 即可。

Private Sub about_Click()
MsgBox "中華民國電腦技能基金會考題", , "關於" ' 說明 => 關於 顯示的內容
End Sub

Private Sub copy_Click()
txtContent.Tag = txtContent.SelText
' 把資料存放在 txtContent 物件的 Tag 屬性中 (Tag 屬性是拿來存資料的，也可以設個變數存起來)
' SelText 的意思是 目前選取 (反白) 到的字串
End Sub

Private Sub cut_Click()
txtContent.Tag = txtContent.SelText
txtContent.SelText = ""
' 把資料存放在 txtContent 物件的 Tag 屬性中 (Tag 屬性是拿來存資料的，也可以設個變數存起來)
' 由於是剪下，所以在存好資料後必須將 SelText (反白的地方) 改成 "" 空字串
End Sub

Private Sub end_Click()
End ' 結束指令
End Sub

Private Sub Form_Load() ' 當表單一開始載入時
txtContent.Top = Me.ScaleTop ' TextBox 物件的長度 寬度 大小 等於 表單的長度 寬度 大 小
txtContent.Left = Me.ScaleLeft ' 正常來說 長度 寬度 大小是由 Top Left Width Height 控制
txtContent.Width = Me.ScaleWidth ' 但前面加上 Scale 的意思是 物件內部
txtContent.Height = Me.ScaleHeight ' ScaleHeight = 物件內部的高度 .. 以此類推
save.Enabled = False ' 關閉存檔功能
End Sub
Private Sub Form_Resize() ' 當表單大小有改變時
txtContent.Top = Me.ScaleTop ' 因為 TextBox 要隨著 表單改變的大小改變 所以必須在 Resize 事件中也跟著跑
txtContent.Left = Me.ScaleLeft
txtContent.Width = Me.ScaleWidth
txtContent.Height = Me.ScaleHeight
End Sub

Private Sub NewFile_Click()
txtContent.Text = "" ' 清空原本 TextBox 中的文字
Me.Caption = "New" ' 表單名稱改成 New
save.Enabled = False ' 存檔的功能關閉
End Sub

Private Sub open_Click()
On Error GoTo errorsave ' On Error GoTo 標籤 意思是 當發生錯誤時 則 GoTo 跳到 標籤的位置
    
CMDialog.ShowOpen ' ShowOpen 是開啟檔案 ShowSave 是儲存檔案
Me.Caption = CMDialog.FileName ' 表單的名稱要變成目前檔案的路徑
Open CMDialog.FileName For Input As #1 ' 開啟檔案的指令是 Open 檔案路徑 For Input / Output As 編號 (Input 為開啟 Output 為存檔)
' Open 打開 CMDialog.FileName 是 前面 ShowOpen 後會跳出一個開啟檔案的視窗 而他選到檔案的路徑
' 假設 ShowOpen 後 我從那個視窗到 C 碟 選了一個 ABC.Txt 的檔案 則 CMDialog.FileName = "C:\ABC.Txt"
' 假如 開啟後選擇取消 則 CMDialog.FileName = "" 空字串 而 Open 空字串會發生錯誤則會 Goto errorsave
' (因為第一行的 On Error Goto errorsave 的關係)

' 設目前 Open 打開了一個 XXX.Txt
Do While Not EOF(1) ' 直到讀取到檔案的底部 (Txt 檔的最底)
    Line Input #1, A ' 整行讀取 #1 (編號的資料) 把資料讀取到 A 變數當中 (Input 編號,變數) 為讀取資料 前面加上 Line Input 則是整行讀取
    txtContent.Text = txtContent.Text & A & vbCrLf ' TextBox 的資料 = 原本的資料 加上 A 變數 (讀到的資料) 在加上換行
Loop

Close #1 ' 關閉的檔案 (因為已經讀完了 可以關閉了)

save.Enabled = True ' 開啟存檔的功能

errorsave: ' 這個是上面 On Error Goto 標籤 的 標籤
    Exit Sub  ' 標籤的動作就是 Exit Sub 結束目前的動作 (按下按鈕所需要執行的動作直接跳開)
End Sub

Private Sub paste_Click()
txtContent.SelText = txtContent.Tag ' 貼上就是把目前反白的資料 或是 目前滑鼠所在的位置的資料取代成 txtContent.Tag (txtContent.Tag 可以用變數取代 但必須跟複製的變數一樣 )
End Sub

Private Sub save_Click() ' 這個是儲存檔案
On Error GoTo errorsave ' 同開啟

Open Me.Caption For Output As #1 ' 同開啟 Output 是存檔 檔案路徑為目前的 表單名稱 ( 目前檔案開啟的路徑 )
Print #1, txtContent.Text
' 存檔的方式為 Print 編號,內容
Close ' 同開啟

errorsave:
    Exit Sub ' 同開啟
End Sub

Private Sub saveas_Click() ' 另存新檔
On Error GoTo errorsave ' 同開啟

CMDialog.ShowSave ' 同開啟
A = CMDialog.FileName ' 存檔路徑
Open A For Output As #1 ' 開啟 路徑 A 的檔案 設置為 存檔模式 Output
Print #1, txtContent.Text ' 存檔的方式為 Print 編號,內容
Close ' 同開啟
Me.Caption = A ' 表單名稱改為 目前新路徑的路徑

errorsave: ' 同開啟
    Exit Sub ' 同開啟
End Sub

401 詳細講義.rar

#0xDe 從分享中學習

#Facebook：ProgrammerDe (https://www.facebook.com/MicrosoftDes) 有問題歡迎提問

回首頁