.Net 知識家

'-------------------------------------------------------------------
'有輸入暗碼的 InputBox
'在 VBA InputBox 可以隱藏輸入的字符
'
'作者︰Daniel Klann
'日期︰2003年3月
'譯者︰cg1    (http://access911.net)
'環境︰Windows XP + Access 2003 測試通過
'-------------------------------------------------------------------

'需要引用 WIN32 API
Private Declare Function CallNextHookEx _
    Lib "user32" (ByVal hHook As Long, _
                    ByVal ncode As Long, _
                    ByVal wParam As Long, _
                    lParam As Any) As Long

Private Declare Function GetModuleHandle _
    Lib "kernel32" Alias "GetModuleHandleA" _
        (ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx _
    Lib "user32" Alias "SetWindowsHookExA" _
                    (ByVal idHook As Long, _
                    ByVal lpfn As Long, _
                    ByVal hmod As Long, _
                    ByVal dwThreadId As Long) As Long

Private Declare Function UnhookWindowsHookEx _
    Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage _
    Lib "user32" Alias "SendDlgItemMessageA" _
        (ByVal hDlg As Long, _
        ByVal nIDDlgItem As Long, _
        ByVal wMsg As Long, _
        ByVal wParam As Long, _
        ByVal lParam As Long) As Long

Private Declare Function GetClassName _
    Lib "user32" Alias "GetClassNameA" _
        (ByVal hwnd As Long, _
        ByVal lpClassName As String, _
        ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'定義 API 中需要引用的常數
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, _
                        ByVal wParam As Long, _
                        ByVal lParam As Long) As Long
    Dim RetVal
    Dim strClassName As String, lngBuffer As Long

    If lngCode < HC_ACTION Then
        NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
        Exit Function
    End If

    strClassName = String$(256, " ")
    lngBuffer = 255

    If lngCode = HCBT_ACTIVATE Then                             '當前被激活的窗體
        RetVal = GetClassName(wParam, strClassName, lngBuffer)
        If Left$(strClassName, RetVal) = "#32770" Then          '獲取 InputBox 的類名
            '用 * 星號替換文本框中顯示的字符
            'Asc("*") 可以替換，你可以用其他字符代替
            SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
        End If

    End If

    '以下這行確保其他鉤子能夠被正確調用
    CallNextHookEx hHook, lngCode, wParam, lParam

End Function

Public Function InputBoxDK(Prompt, _
                            Optional Title, _
                            Optional Default, _
                            Optional XPos, _
                            Optional YPos, _
                            Optional HelpFile, _
                            Optional Context) As String
    Dim lngModHwnd As Long, lngThreadID As Long

    lngThreadID = GetCurrentThreadId
    lngModHwnd = GetModuleHandle(vbNullString)
    hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
    InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
    UnhookWindowsHookEx hHook
End Function

Function test()
'按 ALT + F11 後插入一個模塊，然後將所有代碼 COPY 進去後，
'將光標停在這裡，然後按 F5
    MsgBox InputBoxDK("dfasd")
End Function

引用自http://access911.net/fixhtm/72FABE1E16DCE7F3_big5.htm?tt=